Deserialized a list! Restructured project!

I finally got deserializing lists working. Exposing them to QML was not a trivial task either. Note that I didn't do it the clean way. Nested lists are not supported. But it works! Because I got so frustarted at one point trying to implement things the right way, I restructured the project to seperate the Sailfish code from the Qt code and created a new, empty desktop project. The Qt code has been transformed into a happy little library, to which the Sailfish OS application links. Note that QMake doesn't seem to strip the library for some reason.
2025-09-05 10:12:46 +00:00 · 2020-10-08 03:00:08 +02:00 · 2020-10-08 03:00:08 +02:00 · 1e80ceb697
commit 1e80ceb697
parent 4e3395c4e5
77 changed files with 507 additions and 213 deletions
--- a/sailfish/qml/pages/LegalPage.qml
+++ b/sailfish/qml/pages/LegalPage.qml
@ -0,0 +1,128 @@
+/*
+Sailfin: a Jellyfin client written using Qt
+Copyright (C) 2020 Chris Josten
+
+This library is free software; you can redistribute it and/or
+modify it under the terms of the GNU Lesser General Public
+License as published by the Free Software Foundation; either
+version 2.1 of the License, or (at your option) any later version.
+
+This library is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+Lesser General Public License for more details.
+
+You should have received a copy of the GNU Lesser General Public
+License along with this library; if not, write to the Free Software
+Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
+*/
+import QtQuick 2.6
+import QtQuick.XmlListModel 2.0
+import Sailfish.Silica 1.0
+
+import "../components"
+
+/**
+ * This page contains legal information about snippets and 3rd party libraries.
+ *
+ * Displaying them is done by loading ../3rdparty.xml, which contains a list of all
+ * the included snippets/libraries and their licenses.
+ */
+Page {
+    allowedOrientations: Orientation.All
+
+    SilicaFlickable {
+        anchors.fill: parent
+        contentHeight: content.height
+
+        Column {
+            id: content
+            width: parent.width
+
+            XmlListModel {
+                id: licencesModel
+                source: Qt.resolvedUrl("../3rdparty.xml")
+                query: "/includes/include"
+                XmlRole { name: "name"; query: "name/string()" }
+                XmlRole { name: "type"; query: "type/string()" }
+                XmlRole { name: "url"; query: "url/string()" }
+                XmlRole { name: "copyright"; query: "license/copyright/string()" }
+                XmlRole { name: "licenseUrl"; query: "license/text/string()" }
+                XmlRole { name: "licenseType"; query: "license/type/string()" }
+            }
+
+            PageHeader {
+                title: qsTr("Legal")
+            }
+
+            PlainLabel {
+                text: qsTr("Sailfin contains code taken from other projects. Without them, Sailfin would " +
+                           "not be possible!")
+            }
+
+            Repeater {
+                model: licencesModel
+                Column {
+                    width: parent.width
+                    SectionHeader {
+                        text: name
+                    }
+
+                    PlainLabel {
+                        color: Theme.secondaryHighlightColor
+                        text: {
+                            switch(type) {
+                            case "SNIPPET":
+                                return qsTr("This program contains small snippets of code taken from <a href=\"%1\">%2</a>, which " +
+                                        "is licensed under the %3 license:")
+                                    .arg(model.url).arg(model.name).arg(model.licenseType);
+                            }
+                        }
+                    }
+
+                    Item {
+                        width: 1
+                        height: Theme.paddingLarge
+                    }
+
+                    SilicaFlickable {
+                        anchors {
+                            left: parent.left
+                            right: parent.right
+                            leftMargin: Theme.horizontalPageMargin
+                            rightMargin: Theme.horizontalPageMargin
+                        }
+                        height: licenseLabel.contentHeight
+                        contentWidth: licenseLabel.contentWidth
+                        clip: true
+
+                        Label {
+                            id: licenseLabel
+                            color: Theme.secondaryHighlightColor
+                            font.family: "monospace"
+                            font.pixelSize: Theme.fontSizeExtraSmall
+                            wrapMode: Text.NoWrap
+
+                            Component.onCompleted: {
+                                var xhr = new XMLHttpRequest;
+                                xhr.open("GET", Qt.resolvedUrl("../" + model.licenseUrl)); // set Method and File
+                                console.log(Qt.resolvedUrl("../" + model.licenseUrl))
+                                xhr.onreadystatechange = function () {
+                                    if (xhr.readyState === XMLHttpRequest.DONE){ // if request_status == DONE
+                                        var response = model.copyright + "\n\n" + xhr.responseText;
+                                        console.log(response);
+                                        licenseLabel.text = response
+                                    }
+                                }
+                                xhr.send(); // begin the request
+                            }
+                        }
+                        HorizontalScrollDecorator {}
+                    }
+                }
+            }
+
+            VerticalScrollDecorator {}
+        }
+    }
+}