mirror of
https://github.com/HenkKalkwater/harbour-sailfin.git
synced 2024-10-05 04:28:22 +00:00
Chris Josten
edcd3a93af
I've dropped the whole `<constant> * Theme.pixelRatio`-approach[^1] for determining when the UI should split into two columns, because the values seemed quite arbitrary and I was entering random numbers. I'm now doing it on multiples of `Theme.itemSizeHuge`, which is easier to reason about. This also fixes occasions where items in a grid would leave a bit of space to the right in the CollectionPage. Backdrop images in VideoPage and MusicAlbumPage now have a maximum height of half of the screen, to avoid filling the entire screen in landscape mode. Perhaps it doesn't always look good, but it makes the layout more usable. Images on the SeasonPage and MusicAlbumPage (in landscape) are now aligned to the right, to avoid blocking the Page back indicator.
115 lines
4.5 KiB
QML
115 lines
4.5 KiB
QML
/*
|
|
Sailfin: a Jellyfin client written using Qt
|
|
Copyright (C) 2020-2024 Chris Josten
|
|
|
|
This library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
This library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with this library; if not, write to the Free Software
|
|
Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
|
*/
|
|
import QtQuick 2.6
|
|
import Sailfish.Silica 1.0
|
|
import QtQuick.Layouts 1.1
|
|
|
|
import nl.netsoj.chris.Jellyfin 1.0 as J
|
|
|
|
import "../../components"
|
|
import "../../components/music"
|
|
import "../.."
|
|
|
|
BaseDetailPage {
|
|
id: albumPageRoot
|
|
readonly property int _songIndexWidth: 100
|
|
property bool _collectionModelLoaded: false
|
|
readonly property bool _twoColumns: gridColumnCount > 4
|
|
readonly property string _description: {
|
|
if (itemData.type === "MusicAlbum") {
|
|
//: Short description of the album: %1 -> album artist, %2 -> amount of songs, %3 -> duration, %4 -> release year
|
|
qsTr("%1\n%2 songs | %3 | %4")
|
|
.arg(itemData.albumArtist)
|
|
.arg(itemData.childCount)
|
|
.arg(Utils.ticksToText(itemData.runTimeTicks))
|
|
//: Unknown album release year
|
|
.arg(itemData.productionYear >= 0 ? itemData.productionYear : qsTr("Unknown year"))
|
|
} else {
|
|
qsTr("Playlist\n%1 songs | %2")
|
|
.arg(itemData.childCount)
|
|
.arg(Utils.ticksToText(itemData.runTimeTicks))
|
|
}
|
|
}
|
|
|
|
J.ItemModel {
|
|
id: collectionModel
|
|
loader: J.UserItemsLoader {
|
|
apiClient: appWindow.apiClient
|
|
sortBy: itemData.type === "MusicAlbum" ? "ParentIndexNumber,IndexNumber,SortName" : ""
|
|
fields: [J.ItemFields.ItemCounts, J.ItemFields.PrimaryImageAspectRatio]
|
|
parentId: itemData.jellyfinId
|
|
autoReload: itemData.jellyfinId.length > 0
|
|
//onParentIdChanged: if (parentId.length > 0) reload()
|
|
}
|
|
}
|
|
RowLayout {
|
|
anchors.fill: parent
|
|
|
|
|
|
SilicaListView {
|
|
id: list
|
|
Layout.fillHeight: true
|
|
Layout.fillWidth: true
|
|
model: collectionModel
|
|
header: Loader {
|
|
width: parent.width
|
|
source: "../../components/music/NarrowAlbumCover.qml"
|
|
onLoaded: bindAlbum(item)
|
|
}
|
|
section {
|
|
property: itemData.type === "MusicAlbum" ? "parentIndexNumber" : ""
|
|
delegate: SectionHeader {
|
|
text: qsTr("Disc %1").arg(section)
|
|
}
|
|
}
|
|
delegate: SongDelegate {
|
|
id: songDelegate
|
|
name: model.name
|
|
artists: model.artistItems
|
|
duration: model.runTimeTicks
|
|
indexNumber: itemData.type === "MusicAlbum" ? model.indexNumber : index + 1
|
|
onClicked: window.playbackManager.playItemInList(collectionModel, model.index)
|
|
}
|
|
|
|
VerticalScrollDecorator {}
|
|
}
|
|
Item {height: 1; width: Theme.paddingLarge; visible: wideAlbumCover.visible; }
|
|
Loader {
|
|
id: wideAlbumCover
|
|
visible: _twoColumns
|
|
Layout.minimumWidth: gridCellSize * 2
|
|
Layout.fillHeight: true
|
|
source: visible
|
|
? "../../components/music/WideAlbumCover.qml" : ""
|
|
onLoaded: bindAlbum(item)
|
|
}
|
|
Item {height: 1; width: Theme.horizontalPageMargin; visible: wideAlbumCover.visible; }
|
|
}
|
|
|
|
function bindAlbum(item) {
|
|
item.albumArt = Qt.binding(function(){ return Utils.itemImageUrl(apiClient.baseUrl, itemData, "Primary", {"maxWidth": parent.width})})
|
|
item.name = Qt.binding(function(){ return itemData.name})
|
|
item.listview = Qt.binding(function() { return list})
|
|
item.aspectRatio = Qt.binding(function() { return itemData.primaryImageAspectRatio})
|
|
item.blurhash = Qt.binding(function() { return itemData.imageBlurHashes["Primary"][itemData.imageTags["Primary"]]; })
|
|
item.twoColumns = Qt.binding(function() { return _twoColumns })
|
|
item.description = Qt.binding(function() { return _description })
|
|
}
|
|
}
|